18.09.2012 09:20:13

Захват видео с WEB камеры и детектор движения

Довольно часто возникает необходимость определения движения в видеопотоке (например, в охранных целях — это гораздо дешевле и надёжнее, чем ставить живого оператора). Сегодня я вам расскажу, как написать простенький детектор движения, используя только веб камеру.

Так как у нас, программистов, принято разбивать задачи на подзадачи, то у нас есть две подзадачи: первая — научиться захватывать видео с камеры (для простоты возьмём Web-камеру), а вторая, собственно — определять движение.

Скажу сразу, что писать я буду на Delphi. Кому не нравится — могут не читать.

Итак, без лишних слов, приступим.

Захват видео

Всё зависит от типа вашей камеры. Самые распространённые — это web-камеры. Сегодня они есть почти в каждом ноутбуке. Для захвата видео с веб-камеры существует множество инструментов. Наиболее часто используемый — библиотека AVICAP32.DLL, хотя есть и другие.

Создадим и добавим в проект модуль AviCap32Unit.pas, где опишем внешние функции и константы библиотеки AVICAP32.DLL. Нам понадобятся две функции: capGetDriverDescriptionA и capCreateCaptureWindowA. Для чего они нужны — расскажу позже. Ещё нам нужны 4 сообщения: WM_CAP_START, WM_CAP_DRIVER_CONNECT, WM_CAP_GRAB_FRAME и WM_CAP_STOP.

Код модуля AviCap32Unit:

unit AviCap32Unit;
interface
uses windows,Messages;
const
  WM_CAP_START = WM_USER;
  WM_CAP_DRIVER_CONNECT = WM_CAP_START + 10;
  WM_CAP_GRAB_FRAME = WM_CAP_START + 60;
  WM_CAP_STOP = WM_CAP_START + 68;
function capCreateCaptureWindowA(
  lpszWindowName : PAnsiCHAR;
  dwStyle : longint;
  x : integer;
  y : integer;
  nWidth : integer;
  nHeight : integer;
  ParentWin : HWND;
  nId : integer): HWND; stdcall external 'AVICAP32.DLL';
function capGetDriverDescriptionA(
  wDriverIndex        : UINT;
  lpszName            : LPSTR;
  cbName              : Integer;
  lpszVer             : LPSTR;
  cbVer               : Integer): BOOL; stdcall; external 'AVICAP32.DLL';
implementation
end.

Ну, у нас есть две функции и четыре константы. «Что же с ними делать?» – спросите вы. Можно уже использовать готовые функции, а можно создать класс для работы с Web-камерой. Второй вариант предпочтительней, поскольку вы можете унаследовать ещё класс (например, для IP-камер), в котором механизм захвата устроен по-другому, а нам только надо получить кадр. Напишем модуль CamCaptureUnit. Я думаю, там всё понятно. Если что не понятно — пишите в комментарии.

Код модуля CamCaptureUnit:

unit CamCaptureUnit;
interface
uses Windows,Graphics,AviCap32Unit;
type TCamera=class
      protected
        FWidth    : integer;
        FHeight   : integer;
        FCamIndex : integer;
        Fh        : THandle;
        FName     : string;
        FVer      : string;
      public
        Constructor Create;
        Destructor Destroy; override;
        function Start():boolean;
        function CaptureBMP(bmp:TBitmap):boolean;
        property CamIndex:integer read FCamIndex write FCamIndex;
        property Name:string read FName write FName;
        property Ver:string read FVer write FVer;
      end;
     TCamList=class
      protected
        FList : array of TCamera;
        function FGetCount:integer;
        function FGetItem(index:integer):TCamera;
      public
        procedure Emumerate();
        property count:integer read FGetCount;
        property List[index:integer]:TCamera read FGetItem; default;
      end;
 
implementation
 
Constructor TCamera.Create;
begin
  inherited;
  Fh:=0;
  FWidth:=640;
  FHeight:=480;
end;
 
Destructor TCamera.Destroy;
begin
  if(Fh<>0)then CloseHandle(Fh);
  inherited;
end;
 
function TCamera.Start():boolean;
begin
  Fh:=capCreateCaptureWindowA('test',
    WS_VISIBLE or WS_CHILD,
    10000,
    10000,
    FWidth,
    FHeight,
    GetDesktopWindow,
    0);
  if(fh<>0)then
    begin
    SendMessage(Fh, WM_CAP_DRIVER_CONNECT, 0, 0);
    result:=true;
    end else
    begin
    result:=false;
    end;
end;
 
function TCamera.CaptureBMP(bmp:TBitmap):boolean;
var tdc: HDC;
begin
  SendMessage(Fh, WM_CAP_GRAB_FRAME,0,0);
  bmp.Width:=FWidth;
  bmp.Height:=FHeight;
  tdc := GetDC(Fh);
  BitBlt(bmp.Canvas.Handle, 0, 0, FWidth, FHeight, tdc, 0, 0, SRCCOPY);
  ReleaseDC(Fh, tdc);
  result:=true;
end;
 
function TCamList.FGetCount:integer;
begin
  result:=length(FList);
end;
 
function TCamList.FGetItem(index:integer):TCamera;
begin
  result:=FList[index];
end;
 
procedure TCamList.Emumerate();
var i       : integer;
    name    : array[0..255]of AnsiChar;
    ver     : array[0..255]of AnsiChar;
    cam     : TCamera;
begin
 for i:=0 to 9 do
  begin
  if(capGetDriverDescriptionA(i,@name,SizeOf(name),@ver,SizeOf(ver)))then
     begin
     cam:=TCamera.Create;
     cam.Name:=string(name);
     cam.Ver:=string(ver);
     cam.CamIndex:=i;
     SetLength(FList,length(FList)+1);
     FList[High(FList)]:=cam;
     end;
  end;
end;
end.

Как видите, тут есть два класса — TCamera и TCamList. Самый необходимый для нас метод — TCamera.CaptureBMP. Он реализует захват кадра с камеры.

На главной форме располагаем один компонент TImage; — для вывода картинки, один ComboBox — для списка камер, одну кнопку (TButton или любую другую) — для запуска или остановки захвата видео, CheckBox — для запуска или остановки анализатора движения, и ещё таймер — для получения кадров. В private формы опишем список камер: CamList : TCamList; и саму камеру: cam: TCamera;

При создании формы, перебираем камеры в системе:

procedure TMainForm.FormCreate(Sender: TObject);
var i:integer;
begin
  CamList:=TCamList.Create;
  CamList.Emumerate;
  if(CamList.count=0)then
    begin
    ShowMessage('No cams detected!');
    Application.Terminate;
    exit;
    end;
  CamListCB.items.BeginUpdate;
  try
    CamListCB.items.Clear;
    for i:=0 to CamList.count-1 do
      CamListCB.items.AddObject(CamList[i].Name,CamList[i]);
    CamListCB.ItemIndex:=0;
  finally
    CamListCB.items.EndUpdate;
  end;
end;

При нажатии на «Старт» — запускаем камеру:

procedure TMainForm.StartButtonClick(Sender: TObject);
begin
  cam:=CamList[CamListCB.ItemIndex];
  if(cam.Start)then
    begin
    CamListCB.Enabled:=false;
    CamTimer1.Enabled:=true;
    end;
end;

По таймеру получаем картинку:

procedure TMainForm.CamTimer1Timer(Sender: TObject);
var BMP  : TBitmap;
begin
  bmp:=TBitmap.Create;
  try
    cam.CaptureBMP(bmp);
    Image1.Picture.Assign(bmp);
  finally
    bmp.Destroy;
  end;
end;

Компилируем, запускаем, наслаждаемся результатом:

Анализ полученных кадров и определение движения

Теперь начинается самое интересное. Пособий о том, как получать изображение с камеры — полным полно в интернете. Нас же интересует определение движения. Скажу вам, что результат захватывает.

Для начала — немного теории. Мы будем использовать самый простой, однако, довольно эффективный и наиболее часто используемый метод — сравнение двух соседних кадров. Что же необходимо для этого?

Самый простой метод сравнения — это, конечно, попиксельное вычитание. Нам просто необходимо из каждого пикселя текущего кадра вычесть каждый пиксель предыдущего. Ну, и если разница = 0, то движения не было вовсе. Однако, на камере всегда присутствуют шумы, иногда пролетают мошки, комары... Поэтому мы не будем сравнивать разницу с нулём, а считать, что движение произошло, если модуль разницы меньше константы D Эта константа определяется опытным путём, числа 50 (из 255 возможных для каждого цвета) вполне достаточно.

Для кадра размером 640x480 и трёх цветов (красный, зелёный, синий) это будет: 640*480*3 = 921600 операций вычитания — почти миллион! И это не раз в секунду, а намного чаще (в идеале - 24 раза, но обычно количество кадров уменьшают до нескольких штук в секунду). Плюс, ещё надо их сравнить. Довольно ресурсоёмко...

Именно поэтому картинку приводят к чёрно-белому варианту и уменьшают в несколько раз. Мы каждый кадр тоже будем обесцвечивать и уменьшать (делить) на константу divisor.

Ну, алгоритм ясен:

Получили картинку с камеры;
Привели её к оттенкам серого для каждого пикселя: (R+G+B) div 3;
Поделили на делитель (например, было 640x480, делитель = 8, итоговый кадр будет 80x60);
Из полученной матрицы отнимаем матрицу, полученную на предыдущем кадре - получаем матрицу разницы (diff);
Считаем количество элементов diff, значение которых меньше D;
Если количество больше предельного K, то подаём сигнал тревоги.

Весь алгоритм реализуем в классе TMotionDetector

unit MotionDetectorUnit;
interface
uses graphics;
type
  TMotionDetector = class
   private
    FOldBMP     : TBitmap;
    FOldMatrix  : array of array of byte;
    FNewMatrix  : array of array of byte;
    FDiffMatrix : array of array of byte;
    FNewBMP     : TBitmap;
    Fdivisor    : integer;
    function FGetWidth():integer;
    function FGetHeight():integer;
    function FGetOldM(x,y:integer):byte;
    function FGetNewM(x,y:integer):byte;
    function FGetDiffM(x,y:integer):byte;
   public
    function PushBitmap(bmp:TBitmap):boolean;
    function DetectMotion():boolean;
    property width:integer read FGetWidth;
    property height:integer read FGetHeight;
    property divisor:integer read Fdivisor write Fdivisor;
    property OldM[X, Y: Integer]:byte read FGetOldM;
    property NewM[X, Y: Integer]:byte read FGetNewM;
    property DiffM[X, Y: Integer]:byte read FGetDiffM;
    constructor Create;
    destructor Destroy; override;
   end;
implementation
uses SysUtils;
 
function TMotionDetector.FGetOldM(x,y:integer):byte;
begin
  if((not Assigned(FOldBMP))or(not Assigned(FNewBMP)))then
    exit(0);
  result:=FOldMatrix[x,y];
end;
 
function TMotionDetector.FGetNewM(x,y:integer):byte;
begin
  if((not Assigned(FOldBMP))or(not Assigned(FNewBMP)))then
    exit(0);
  result:=FNewMatrix[x,y];
end;
 
function TMotionDetector.FGetDiffM(x,y:integer):byte;
begin
  if((not Assigned(FOldBMP))or(not Assigned(FNewBMP)))then
    exit(0);
  result:=FDiffMatrix[x,y];
end;
 
function TMotionDetector.DetectMotion():boolean;
type TRGB=packed record
        R : byte;
        G : byte;
        B : byte;
      end;
     TLine=array[0..65535]of TRGB;
     PLine=^TLine;
var x,y,yy,xx,w,h,i,j  : integer;
    lines           : array of PLine;
    sum             : integer;
    point           : TRGB;
    d_n,d_o         : integer;
begin
  if((not Assigned(FOldBMP))or(not Assigned(FNewBMP)))then
    exit(false);
  w:=length(FNewMatrix);
  SetLength(FOldMatrix,w);
  for x:=0 to w-1 do
    begin
    h:=length(FNewMatrix[x]);
    SetLength(FOldMatrix[x],h);
    for y:=0 to h-1 do
      FOldMatrix[x,y]:=FNewMatrix[x,y];
    end;
  //
  w:=FNewBMP.Width div Fdivisor;
  h:=FNewBMP.Height div Fdivisor;
  //
  SetLength(FNewMatrix,w);
  for x:=0 to w-1 do
    SetLength(FNewMatrix[x],h);
  //Convert New BMP to mask
  SetLength(lines,Fdivisor);
  for y:=0 to h-1 do
    begin
    yy:=y*Fdivisor;
    for i:=0 to Fdivisor-1 do
      lines[i]:=FNewBMP.ScanLine[yy+i];
    for x:=0 to w-1 do
      begin
      xx:=x*Fdivisor;
      sum:=0;
      for i:=0 to Fdivisor-1 do
        for j:=0 to Fdivisor-1 do
          begin
          point:=lines[i][xx+j];
          sum:=sum+((point.R+point.G+point.B)div 3);
          end;
      FNewMatrix[x,y]:=(sum div Fdivisor)div Fdivisor;
      end;
    end;
  SetLength(FNewMatrix,FNewBMP.Width div Fdivisor);
  result:=length(FOldMatrix)=length(FNewMatrix);
  if(result)then
    begin
    SetLength(FDiffMatrix,w);
    for x:=0 to w-1 do
      begin
      SetLength(FDiffMatrix[x],h);
      for y:=0 to h-1 do
        begin
        d_n:=FNewMatrix[x,y];
        d_o:=FOldMatrix[x,y];
        //if(d_n>d_o)
        FDiffMatrix[x,y]:=(abs(d_n-d_o) and $FF);
        end;
      end;
    end;
end;
 
function TMotionDetector.FGetWidth():integer;
begin
  if((not Assigned(FOldBMP))or(not Assigned(FNewBMP)))then
    exit(0);
  result:=FOldBMP.Width div Fdivisor;
end;
 
function TMotionDetector.FGetHeight():integer;
begin
  if((not Assigned(FOldBMP))or(not Assigned(FNewBMP)))then
    exit(0);
  result:=FOldBMP.Height div Fdivisor;
end;
 
function TMotionDetector.PushBitmap(bmp:TBitmap):boolean;
begin
  FreeAndNil(FOldBMP);
  FOldBMP:=FNewBMP;
  FNewBMP:=TBitmap.Create;
  FNewBMP.Width:=bmp.Width;
  FNewBMP.Height:=bmp.Height;
  FNewBMP.PixelFormat:=pf24bit;
  FNewBMP.Assign(BMP);
  result:=true;
end;
 
constructor TMotionDetector.Create;
begin
  inherited;
  Fdivisor:=8;
  FOldBMP:=nil;
  FNewBMP:=nil;
end;
 
destructor TMotionDetector.Destroy;
begin
  inherited;
end;
end.

Компилируем, запускаем, наслаждаемся результатом:

Исходник: web-cam-analyzer-src.zip

Exe-шки: web-cam-analyzer-bin.zip

Автор: Консерв в Delphi

Очень понравилась ваша программа но так как мои познания в delfi далеки от того чтоб написать аналогичную программу не могли бы вы более подробно прокомментировать вашу программу буду вам очень благодарен если вам не сложно скиньте на почту. заранее благодарю вас!

07.02.2013 04:41:11

Захват видео с WEB камеры и детектор движения

Захват видео

Анализ полученных кадров и определение движения

Комментарии